! ********************************************************************
!
!  Данная программа входит в набор программ SMs1.inp - SMs10.inp 
!                          учебного пособия:
!   Наседкин А.В. "Конечно-элементное моделирование на основе ANSYS.
!   Программы решения статических задач сопротивления материалов
!   c вариантами индивидуальных заданий" //
!   Ростов-на-Дону: УПЛ РГУ, 1998. 44 с. 
!   
!  Автор программ - Наседкин Андрей Викторович,
!   Ростовский госуниверситет, кафедра математического моделирования,
!   nasedkin@ms.math.rsu.ru или nasedkin@ns.math.rsu.ru
!
! ********************************************************************
/batch           ! Пакетный режим /BATCH
/com,
/com,                 Файл SMs7.inp
/com,    ПРОГРАММА РАСЧЕТА ЗАДАЧИ СОПРОТИВЛЕНИЯ МАТЕРИАЛОВ
/com,    ПО ТЕМЕ: "ПЛОСКИЙ ИЗГИБ БАЛКИ ПЕРЕМЕННОГО СЕЧЕНИЯ"
/com,                  (версия 1.1)
/com,
/com,   Сборник задач по сопротивлению материалов /
/com,   Под ред. В.К. Качурина. М.: Наука, 1970.
/com,            (по задаче 8.14.    С.220-221.)
/com,
/com,   Текстовые результаты сохраняются в файле SMs7.res
/com,   Графические результаты выводятся в файл  Sms7.grph
/com,
/prep7           ! Входим в препроцессор /PREP7
f_r='SMs7'
/show,f_r,grph   ! В режиме /BATCH задаем вывод графики
                 ! в файл <f_r>.grph
antype,static    ! Статический тип анализа
/title, BENDING OF A TAPERED BEAM
                 ! Все данные в системе СГС
h=10           ! Максимальная высота поперечного сечения балки
b=5            ! Ширина поперечного сечения балки
lbeam=100      ! Длина балки
exbeam=2e6     ! Модуль Юнга
mp,ex,1,exbeam ! MAT. PROP. типа MAT=1: модуль Юнга EX=exbeam
q=20           ! Значение распределенной нагрузки
n_el=30        ! Параметр для количества КЭ
et,1,beam54    ! Элементы с TYPE=1 - , балочные КЭ BEAM54
hl=lbeam/n_el  ! Длины КЭ
*dim,x_node,array,n_el+1  ! массив для X-координат узлов
!  В цикле по k заполняется массив X-координат и создаются узлы
*do,k,1,n_el+1
  x_node(k)=hl*(k-1)
  n,k,x_node(k)
*enddo
! Подготовка начальных данных для последующего цикла
! h1, area1, iz1 - высота, площадь и момент инерции соответственно
!                  для левого сечения элемента
h1=h/n_el/10 ! Так как area1 и iz1 не могут равняться нулю,
             ! то h1 полагается равным в 10 раз меньше следующего
             ! значения высоты
area1=b*h1
iz1=b*h1**3/12
! В цикле по k для балки с линейно возрастающей толщиной 
! прямоугольного сечения
! задаются h2, area2 и iz2 для правых сечений КЭ,
! определяются Real Const. для КЭ, создаются КЭ BEAM54,
! задается распределенная нагрузка на КЭ
! и подготавливаются значения h1, area1, iz1 для следующего шага
*do,k,1,n_el
 h2=h*x_node(k+1)/lbeam $ area2=b*h2 $  iz2=b*h2**3/12
 r,k,area1,iz1,h1/2,h1/2,area2,iz2
 rmore,h2/2,h2/2
 real,k
 e,k,k+1
 sfbeam,k,,pres,20 
 h1=h2 $ area1=area2 $ iz1=iz2
*enddo
save
finish  
/solu            ! Входим в решатель /SOLUTION
d,n_el+1,ux,,,,,uy,rotz ! Защемление правого края балки
solve             ! Решаем СЛАУ МКЭ
finish  
/post1
 ! Согласно документации по КЭ BEAM54 
 ! определяем указатели на значения поперечных сил и
 ! изгибающих моментов на концах элементов
etable,sigmai,ls,2  ! Ls,2 - изгибное напряжение 
                    ! на верхней границе сечения в узле I
etable,sigmaj,ls,5  ! Ls,5 - аналог. изгибное напряжение в узле J
etable,mforyi,smisc,2  ! Smisc,2 - поперечная сила Q в узле I
etable,mforyj,smisc,8  ! Smisc,8 - поперечная сила Q в узле J
etable,mmomzi,smisc,6  ! Smisc,6 - изгибающий момент M в узле I
etable,mmomzj,smisc,12 ! Smisc,12 - изгибающий момент M в узле J
/output,F_R,res   ! Направляем вывод в файл <F_R>.res
prnsol,u,y   ! Печатаем прогибы балки
Uymax_ex=-q*lbeam**4/(2*exbeam*iz2) ! Аналитическое значение
!                                     максимального прогиба балки
*vwrite,Uymax_ex 
(1x,'   Uymax_ex= ',f14.5)
prrsol            ! Печатаем опорные реакции
pretab,mforyi,mforyj       ! Печатаем поперечные силы 
pretab,mmomzi,mmomzj       ! Печатаем изгибающие моменты
pretab,sigmai,sigmaj       ! Печатаем изгибные напряжения
/output
/pnum,elem,1  ! Нумеровать элементы при графическом показе
/eshape,1     ! Показать сечение балки в 2d - размерности
eplot         ! Нарисовать элементы
/eshape,0     ! Не показывать сечение балки в 2d - размерности
/pbc,u,,1     ! Показывать граничные условия,
/pbc,f,,1     !                      силы и
/pbc,m,,1     !                      моменты
/psf,pres,norm,1 ! Показывать распределенные нормальные нагрузки
/pnum,elem,1  ! Нумеровать элементы
/pnum,node,0  ! Не нумеровать узлы
/number,1  ! Занумерованные объекты показывать 
           ! только различным цветом без нумерации
eplot
/pbc,all,,0    ! Не показывать граничные условия, силы и моменты
/psf,pres,norm,0 ! Не показывать распределенные нагрузки
/pnum,elem,0     ! Не нумеровать элементы
/triad,off       ! Не показывать начало и систему координат 
pldisp,1   ! Показать деформированное и недеформированное состояние
plls,mforyi,mforyj,2  ! Графический показ эпюры поперечных сил Q 
plls,mmomzi,mmomzj,2  ! Графический показ эпюры изгибающих моментов M
plls,sigmai,sigmaj,2  ! Графический показ эпюры изгибных напряжений
finish 
/exit