/prep7           ! Входим в препроцессор /PREP7

                 ! в файл <F_R>.grph
                 ! Все данные в системе СГС
et,1,beam189
keyopt,1,5,1
!*  
!MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,2.1e11 
MPDATA,PRXY,1,,0.29 
SECTYPE, 1, BEAM, RECT, , 0   
SECOFFSET, CENT 
SECDATA,5,5,0,0,0,0,0,0,0,0,0,0   

lr=500   ! lr, ar, cr - геометрические параметры
ar=400
cr=300
n_fill = 10

k,1              ! Определяем узлы по координатам
k,2,,lr
k,3,,lr
k,4,ar,lr
k,5,ar,lr-cr
l,1,2
l,3,4
l,4,5

lesize,1,,,1
lmesh,1

lesize,2,,,n_fill
lmesh,2

lesize,3,,,1
lmesh,3

CPINTF,UX,
CPINTF,UY,

finish  
/solu            ! Входим в решатель /SOLUTION
antype,static    ! Статический тип анализа
d,1,uy           ! Задаем условия закрепления
d,1,ux
d,1,rotz
d,5+2*n_fill,uy
d,5+2*n_fill,ux           
*do,i,2,1+n_fill
 sfbeam,i,,pres,40  ! Задаем распределенную нагрузку
*enddo
     ! Задание сил FY, FX и моментов MZ проводится аналогично
     ! описанному в программе SMs2.inp
solve             ! Решаем СЛАУ МКЭ
save
finish 

/post1
SET,FIRST   
 ! Согласно документации по КЭ BEAM3 при KEYOPT(9)=0
 ! определяем указатели на значения нормальных и поперечных сил и
 ! изгибающих моментов на концах элементов
etable,mforxi,smisc,1  ! Smisc,1 - нормальная сила N в узле I
etable,mforxj,smisc,7  ! Smisc,7 - нормальная сила N в узле J
etable,mforyi,smisc,2  ! Smisc,2 - поперечная сила Q в узле I
etable,mforyj,smisc,8  ! Smisc,8 - поперечная сила Q в узле J
etable,mmomzi,smisc,6  ! Smisc,6 - изгибающий момент M в узле I
etable,mmomzj,smisc,12 ! Smisc,12 - изгибающий момент M в узле J
/output,F_R,res   ! Направляем вывод в файл <F_R>.res
prrsol            ! Печатаем опорные реакции
pretab,mforyi,mforyj       ! Печатаем поперечные силы
pretab,mforxi,mforxj       ! Печатаем нормальные силы
pretab,mmomzi,mmomzj       ! Печатаем изгибающие моменты

/output
plls,mforyi,mforyj,-2  ! Графический показ эпюры поперечных сил Q 
  ! Поперечные силы в ANSYS имеют противоположный знак 
  ! по сравнению с принятым в указанном выше задачнике
plls,mforxi,mforxj,2   ! Графический показ эпюры нормальных сил N
plls,mmomzi,mmomzj,2   ! Графический показ эпюры изгибающих моментов M
finish