
СТАТИЧЕСКОЕ ДЕФОРМИРОВАНИЕ ПЬЕЗОКЕРАМИЧЕСКОГО ПРЕОБРАЗОВАТЕЛЯ С МНОГОЭЛЕКТРОДНЫМ ПОКРЫТИЕМ
ПОД ДЕЙСТВИЕМ ЗАДАННОЙ РАЗНОСТИ ПОТЕНЦИАЛОВ НА ЭЛЕКТРОДАХ

	ЗАДАНИЕ
	Необходимо исследовать поведение анизотропного диска при статическом деформировании, изготовленного из пьезокерамики PZT-4 со следующими параметрами: плотность ; модули упругости в   , , , ; пьезомодули в :  , , ; значения диэлектрических проницаемостей: , .
На Рис. 1 приведена схема меридионального сечения диска с направлениями поляризации , шириной диска ,  значение электрического потенциала на электродах и суммарным поверхностным зарядом  на электроде в центре схемы. , .

КОНЕЧНО – ЭЛЕМЕНТНАЯ СЕТКА И ГРАНИЧНЫЕ УСЛОВИЯ

КАРТИНА ДЕФОРМИРОВАННОЙ ФОРМЫ

КОД ПРОГРАММЫ В ANSYS
	/CLEAR
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15

/TITLE, PIEZOELECTRIC DISC
H=4e-3
a1=3e-2
a2=4e-2
a3=3e-2

R1 = a1
R2 = a1 + a2
R3 = a1 + a2 + a3

VINP=10
SM=1
HDIV=8*SM
R1DIV=16*SM
R12DIV=32*SM
R23DIV=16*SM

RO=7.5e3
C11E=13.9e10
C12E=7.78e10
C13E=7.43e10
C33E=11.5e10
C66E=(C11E-C12E)/2.
C44E=2.56e10
E31=-5.2
E33=15.1
E15=12.7
EPS11=730
EPS33=635

/PREP7
MP,DENS,1,RO
TB,ANEL,1
TBDATA,1,C11E,C13E,C12E
TBDATA,7,C33E,C13E
TBDATA,12,C11E
TBDATA,16,C44E
TB,PIEZ,1
TBDATA,2,E31
TBDATA,5,E33
TBDATA,8,E31
TBDATA,10,E15
MP,PERX,1,EPS11
MP,PERY,1,EPS33

ET,1,PLANE223,1001,,1

K,1,0,-H/2
K,2,R1,-H/2
K,3,R2,-H/2
K,4,R3,-H/2
K,5,R3,H/2
K,6,R2,H/2
K,7,R1,H/2
K,8,0,H/2
K,9,R1,0
K,10,R2,0

L,1,2	!1
L,2,3	!2
L,3,4	!3
L,4,5	!4
L,5,6	!5
L,6,7	!6
L,7,8	!7
L,8,1	!8
L,2,9	!9
L,7,9	!10
L,9,10	!11
L,3,10	!12
L,6,10	!13

A,1,2,7,8
A,3,4,5,6
A,2,3,10,9
A,6,7,9,10

LOCAL,11,0,,,,270
CSYS,0
LOCAL,12,0,,,,90
CSYS,0
LOCAL,13,0,,,,180
CSYS,0

ASEL,S,AREA,,1
AATT,1,,1,11

ASEL,S,AREA,,2
AATT,1,,1,12

ASEL,S,AREA,,4
AATT,1,,1,13

ASEL,ALL

LSEL,S,LINE,,8
LSEL,A,LINE,,4
LESIZE,ALL,,,HDIV

LSEL,S,LINE,,9,10
LESIZE,ALL,,,HDIV/2

LSEL,S,LINE,,12,13
LESIZE,ALL,,,HDIV/2

LSEL,S,LINE,,1
LSEL,A,LINE,,7
LESIZE,ALL,,,R1DIV

LSEL,S,LINE,,2
LSEL,A,LINE,,6
LSEL,A,LINE,,11
LESIZE,ALL,,,R12DIV

LSEL,S,LINE,,3
LSEL,A,LINE,,5
LESIZE,ALL,,,R23DIV
LSEL,ALL
LCCAT,1,2,3
LCCAT,5,6,7
MSHKEY,1
MSHAPE,0,2

AMESH,ALL
FINISH

/SOLU
ANTYPE,STAT
OUTRES,ALL,ALL

NSEL,S,LOC,Y,-H/2
NSEL,R,LOC,X,R1,R2
CP,1,VOLT,ALL
*GET,N_VOLT1,NODE,,NUM,MIN

NSEL,S,LOC,Y,H/2
NSEL,R,LOC,X,R1,R2
CP,2,VOLT,ALL
*GET,N_VOLT2,NODE,,NUM,MIN

NSEL,S,LOC,Y,0
NSEL,R,LOC,X,R1,R2
CP,3,VOLT,ALL
*GET,N_VOLT3,NODE,,NUM,MIN

NSEL,S,LOC,X,0
CP,4,VOLT,ALL
*GET,N_VOLT4,NODE,,NUM,MIN

NSEL,S,LOC,X,R3
CP,5,VOLT,ALL
*GET,N_VOLT5,NODE,,NUM,MIN

NSEL,ALL
D,N_VOLT1,VOLT,VINP
D,N_VOLT2,VOLT,VINP
D,N_VOLT3,VOLT,0
F,N_VOLT4,CHRG,0
F,N_VOLT5,CHRG,0

DL,8,,SYMM

NSEL,S,LOC,X,0
D,ALL,UX,0
D,ALL,UY,0

NSEL,ALL
SOLVE
FINISH

/POST1
SET,LAST
/SHOW,WIN32C
/TRIAD,OFF
/PLOPTS,INFO,2
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF
/PLOPTS,FRAME,OFF
/PLOPTS,TITLE,OFF
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF
PLNSOL,U,Y
PLNSOL,EF,SUM
! Постпроцессорный вывод графиков
/PLOPTS,INFO,ON
/COLOR,CURVE,WHIT,1,6 ! цвет графиков - белый (черный при инвертации)
/COLOR,GRID,WHIT, ! цвет сетки - белый (черный при инвертации)
/PLOPTS,TITLE,OFF ! заголовка графика нет
/PLOPT,FRAME,OFF ! рамки нет
/AXLAB,X,r ! подпись к оси X (r)
/AXLAB,Y, E_Z ! подпись к оси Y (z)
/GROPT,DIVX,4 ! Количество делений по оси X
/GROPT,DIVY,4 ! Количество делений по оси Y
/GROPT,DIG2,1 ! Количество цифр после запятой
! Команды определения пути с опорными точками
PATH,XX,4,,120
PPATH,1,,0,H/2
PPATH,2,,R1,H/2
PPATH,3,,R2,H/2
PPATH,4,,R,H/2 ! Определение величины E_Z для построения графика вдоль пути
PDEF,E_Z,EF,Y ! Определение других величин 
PDEF,T_ZZ,S,Y $ PDEF,T_RR,S,X
PDEF,D_Z,D,Y $ PDEF,D_R,D,X $ PDEF,E_R,EF,X
PLPATH,E_Z ! Построение графика E_Z вдоль пути



РАСПРЕДЕЛЕНИЕ ПЕРЕМЕЩЕНИЙ UX

РАСПРЕДЕЛЕНИЕ ПЕРЕМЕЩЕНИЙ UY

МОДУЛЬ ПОЛЯ ПЕРЕМЕЩЕНИЙ

РАСПРЕДЕЛЕНИЕ ЭЛЕКТРИЧЕСКОГО ПОТЕНЦИАЛА

РАСПРЕДЕЛЕНИЕ ИНТЕНСИВНОСТИ НАПРЯЖЕНИЙ (НАПРЯЖЕНИЯ ПО МИЗЕСУ)

РАСПРЕДЕЛЕНИЕ ВЕКТОРА ПЕРЕМЕЩЕНИЙ U
[image: ]
РАСПРЕДЕЛЕНИЕ ВЕКТОРА ЭЛЕКТРИЧЕСКОГО ПОЛЯ

РАСПРЕДЕЛЕНИЕ ВЕКТОРА ЭЛЕКТРИЧЕСКОЙ ИНДУКЦИИ

ГРАФИК КОМПОНЕНТЫ ЭЛЕКТРИЧЕСКОГО ПОЛЯ НА ВЕРХНЕЙ СТОРОНЕ СЕЧЕНИЯ ДИСКА

АНАЛИЗ СХОДИМОСТИ
	SM
	0.25
	0.5
	1
	2

	Max UX
	0.256E-8
	0.257E-8
	0.258E-8
	0.264E-8

	Max EF
	5033.79
	5830.01
	9850.13
	16338.7

	Max D
	0.540E-4
	0.563E-4
	0.926E-4
	0.158E-3


Таб.1. Результаты анализа сходимости
ВЫВОД
Исходя из данных, приведенных в таблице 1 выберем SM=0.5, как оптимальный вариант. При данном значении параметра перемещения по направлению Oy меняются незначительно. Максимальные значения длины вектора напряженности электрического поля неограниченно возрастают в окрестности границ электродированных поверхностей (векторы кранного цвета). Этот эффект вполне ожидаем, поскольку в задачах электроупругости поверхностные электроды являются концентраторами для различных компонент электромеханических полей напряжений, деформаций, напряженности электрического поля и электрической индукции (т.е. для градиентых или потоковых величин, определяемых через производные от перемещений и электрического потенциала).

