
РАСЧЕТ СОБСТВЕННЫХ И УСТАНОВИВШИХСЯ КОЛЕБАНИЙ 
с использованием конечно-элементного пакета ANSYS и программы FlexPDE

	ЗАДАНИЕ

Часть 1. Расчет собственных колебаний составного упругого профиля. 
Пусть тонкая прямоугольная пластина имеет форму буквы «Е». Верхняя часть 1 выполнена из меди с модулем Юнга ; коэффициентом Пуассона  и плотностью . Нижняя часть 2 выполнена из стального материала с модулем Юнга ; коэффициентом Пуассона  и плотностью  = . Размеры буквы указаны в метрах на (Рис. 1). Нижняя грань профиля жестко закреплена. Требуется определить первые четыре собственных частоты профиля в условиях плоского напряженного состояния и вывести картины соответствующих форм колебаний.

Часть 2. Расчет установившихся колебаний составного упругого профиля. 
Определив собственные частоты, провести расчеты установившихся колебаний в заданном диапазоне частот (гармонический анализ) и построить амплитудно-частотные характеристики. При этом задать силовые факторы, которые могли бы возбуждать рассматриваемые моды колебаний (Рис. 2).

	Рис. 1. Размеры пластины для части 1 (в м).
	Рис. 2. Граничные условия для части 2.

	РЕШЕНИЕ ЧАСТИ 1 В ANSYS 
/CLEAR
/FILNAME,St2LM_1
/TITLE, Modal Analysis of an E Region
F_R='Mod_ANS_1'        ! имя файлов для вывода результатов
NFREQ=4        !  число выводимых частот 

/PREP7
W = 5.0               
H = 10.0              
StemW = 1.0           
FlangeT = 1.0         
KFE=FlangeT/2

/OUTPUT,F_R,res
*VWRITE
(1X,'   MODE-FREQUENCY ANALYSIS (Block Lanczos, Plane82)')
*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
/OUTPUT
*DIM,FR,ARRAY,NFREQ  ! массив для собственных частот
!  Материальные константы стали
RO1=7.86e3  ! плотность
E1=2e11     ! модуль Юнга
NU1=0.29    ! коэффициент Пуассона
!  Материальные константы меди
RO2=8.9e3
E2=1.2e11
NU2=0.33
MP,DENS,1,RO1       
MP,EX,1,E1          
MP,NUXY,1,NU1       
MP,DENS,2,RO2       
MP,EX,2,E2          
MP,NUXY,2,NU2       
ET,1,PLANE82    ! КЭ PLANE82:  8-узловой четырехугольный
mshape,1 ! опция треугольной формы 
K,1, 0, 0 $ K,2, W, 0 $ K,3, W, FlangeT
K,4, StemW, FlangeT
K,5, StemW, (H/2 - FlangeT/2)     ! 4.5
K,6, W, (H/2 - FlangeT/2)
K,7, W, (H/2 + FlangeT/2)         ! 5.5
K,8, StemW, (H/2 + FlangeT/2)
K,9, StemW, H - FlangeT           ! 9
K,10,W, H - FlangeT $ K,11,W, H
K,12,0, H $ K,13,0,H/2 $ K,14,W,H/2
L,1,2 $ L,2,3 $ L,3,4 $ L,4,5
L,5,6 $ L,6,14 $ L,14,13 $ L,13,1
AL,1,2,3,4,5,6,7,8
L,14,7 $ L,7,8 $ L,8,9 $ L,9,10 
L,10,11 $ L,11,12 $ L,12,13
AL,7,9,10,11,12,13,14,15 
! Установка сетки конечных элементов
KESIZE,ALL,KFE
ASEL,S,AREA,,2   
AATT,2,,1  
ASEL,ALL  
AMESH,ALL 
*GET,EL_MAX,ELEM,,COUNT  ! EL_MAX - число элементов
*GET,ND_MAX,NODE,,COUNT  ! ND_MAX - число узлов
/OUTPUT,F_r,res,,append
*VWRITE,EL_MAX,ND_MAX
(3X,' NEL_MAX=',F6.0,' NND_MAX=',F6.0)
/COM,
/COM, I   ! Frequency in Hz (ANSYS)
/OUTPUT
SAVE
FINISH

/SOLU
ANTYPE,MODA          
MODOPT,LANB,NFREQ 
NSEL,S,LOC,Y,0	
D,ALL,UX,0    
D,ALL,UY,0    
NSEL,ALL      
OUTRES,ALL,ALL ! Запись результатов 
SOLVE
SAVE
FINISH

/POST1
 ! Вывод резонансных частот в файл
*DO,I,1,NFREQ
  SET,,I
  *GET,FR(I),MODE,I,FREQ
  FRI=FR(I)
  /OUTPUT,F_r,res,,append
  *VWRITE,I,FRI
  (1X,F4.0,'   ',E12.5)
  /OUTPUT
*ENDDO 

	РЕШЕНИЕ ЧАСТИ 1 В FLEXPDE
  title "Modal Analysis of an E Region"

  select
    modes =4 	{number of eigenvalues and modes}
    errlim=0.5e-2

  Variables
    U                   { U and V are the variables }
    V


  definitions
    {geometrical parameters in meters}
    W = 5.0               
	H = 10.0              
	FlangeT = 1.0 
    
	{material properties for copper}
	nu=0.33  E=1.2e11  rho=8.9e3  
    mu  = E/2/(1+nu)	{shear module}
    lambdaL =  2*mu*nu/(1-2*nu)   {Lame's coef}
    lambdaz = 2*mu*lambdaL/(lambdaL+2*mu)
    Sxx = dx(U)	{longitudinal strain Sxx}
    Syy = dy(V)	{longitudinal strain Syy}
    Sxy = (dy(U)+dx(V))/2	{shear strain Sxy}
    Txx= lambdaz*(Sxx+Syy)+2*mu*Sxx       
    Tyy= lambdaz*(Sxx+Syy)+2*mu*Syy       
    Txy=2*mu*Sxy 
    Scal=0.2*globalmax(magnitude(x,y))/globalmax(magnitude(u,v))
    Freq=sqrt(lambda)/(2*pi) {Frequency "f" in Hz}

  equations
	{The displacement equations for modal analysis}
        U:     dx(Txx) + dy(Txy) + lambda*rho*U  = 0
        V:     dx(Txy) + dy(Tyy) + lambda*rho*V  = 0

  boundaries        { regions and boundary conditions }
     Region 1      {upper region 1 from copper}
	start (0,H/2)
	natural(U)=0 natural(V)=0    {free boundary}
	line to (W,H/2) to (W,(H+FlangeT)/2) to (FlangeT,(H+FlangeT)/2)  
	line to (FlangeT,H-FlangeT) to (W,H-FlangeT) to (W,H) to (0,H) to close

     Region 2     {lower region 2 from steel}
	{material properties for steel}
    nu = 0.29 E  = 2e11 rho = 7.86e3  
	start (0,H/2)
	natural(U)=0 natural(V)=0    {free boundary}
	line to (0,0) 
	value(U)=0  value(V)=0 {fixed displacement}
	line to (W,0)
	natural(U)=0 natural(V)=0
	line to (W,FlangeT) to (FlangeT,FlangeT) to (FlangeT,(H-FlangeT)/2)
    line to (W,(H-FlangeT)/2) to (W,H/2) to close

  monitors
    grid(x+Scal*U,y+Scal*V)  as "Mode Shape"
        report Freq as "Frequency in Hz"

  plots      { Resulting Plots }
    grid(x+Scal*U,y+Scal*V)  as "Mode Shape"
        report Freq as "Frequency in Hz"
    summary
        report Freq as "Frequency in Hz"
  end

	РЕЗУЛЬТАТЫ РАБОТЫ ПРОГРАММ (собственные частоты и формы колебаний)

	РЕШЕНИЕ ЧАСТИ 2 В ANSYS 

	РЕШЕНИЕ ЧАСТИ 2 В FLEXPDE 


	RESUME,St2LM_1,db ! считываем базу данных (St2LM_1.db)

/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15

F_R='Harm1'        ! имя файлов для вывода результатов
/SHOW

FORC=1e3
FBEG=4.5       !  начало исследуемого частотного интервала
FEND=5  !  конец частотного интервала
NFREQ=250       !  число рассчитываемых значений по частотам
F1=97.4 $ F2=729.0   

/OUTPUT,F_R,rez
*VWRITE
(1X,'   HARMONIC ANALYS ')
*VWRITE,FBEG,FEND
(1X,'  FBEG=', E12.5,'  FEND=', E12.5)
*VWRITE,NFREQ
(1X,'    NFRQ= ',F4.0)
/OUTPUT

/COM,   Демпфирующие свойства 
PI2=(3.141593*2)
IPI2=1./PI2
FDB=F1
FDE=F2
FRDS=FDB+FDE
Q=1000           ! Добротность конструкции
ADAMP=PI2*FDB*FDE/(FRDS*Q) 
BDAMP=IPI2/(FRDS*Q)

/OUTPUT,F_R,rez,,append
*VWRITE,FDB,FDE
(1X,'   FDB=', E12.5,'  FDE=', E12.5)
*VWRITE,Q
(1X,' Q=', F12.5)
*VWRITE,ADAMP,BDAMP
(1X,'  ADAMP=', E12.5,' BDAMP=',E12.5)
/OUTPUT

/SOLU
ANTYPE,HARMIC          ! Решение задачи об установившихся колебаниях.
HARFRQ,FBEG,FEND       ! Задается расчетный интервал частот.
NSUBST,NFREQ           ! Число частот на заданном интервале: NFREQ.
KBC,1                  ! Постоянное значение амплитуд сил.

ALPHAD,ADAMP  
BETAD,BDAMP

NSEL,S,LOC,X,W     
NSEL,R,LOC,Y,H
*GET,N_RES2,NODE,,NUM,MIN ! Узел с номером N_RES2 - точка (W,H)
NSEL,S,LOC,X,0     
NSEL,R,LOC,Y,H
*GET,N_RES1,NODE,,NUM,MIN ! Узел с номером N_RES1 - точка (0,H)
NSEL,ALL

F,N_RES2,FX,FORC
F,N_RES2,FY,FORC
F,N_RES1,FX,-FORC
F,N_RES1,FY,-FORC

OUTRES,BASIC,ALL ! Сохраняем основные результаты для всех частот
SOLVE
SAVE
FINISH

/POST26
/XRANG,FBEG,FEND
/AXLAB,X,Frequency (Hz)
/AXLAB,Y,Displacement (M)
NSOL,2,N_RES2,UY
PLVAR,2
	  title "Harmonic Vibrations of an E Region "
  variables
    Ur   
    Ui
    Vr   
    Vi
  definitions
    Um = sqrt(Ur^2+Ui^2)     
    Vm = sqrt(Vr^2+Vi^2)     
Scal=0.2*globalmax(magnitude(x,y))/globalmax(magnitude(Um,Vm))
{geometrical parameters in meters}
W = 5.0               
H = 10.0              
FlangeT = 1.0 
{material properties for copper}
nu=0.33  E=1.2e11  rho=8.9e3  
    mu  = E/2/(1+nu)	{shear module}
lambdaL=2*mu*nu/(1-2*nu){Lame's coef}
 lambdaz = 2*mu*lambdaL/(lambdaL+ 2*mu)
    force=1e3
    Freq1=15.8
    Freq2=4.8
    Q=1000           {Q-factor }
    Fsum=Freq1+Freq2 {damping coefficients}
    alpha=pi*2*Freq1*Freq2/(Fsum*Q)
    beta = 1/(pi*2*Fsum*Q)
    omega = 2*pi*freq1 {calc results for freq1}

  {real and imaginary parts of the strains}
    Srxx = dx(Ur)	
    Sryy = dy(Vr)
    Srxy = (dy(Ur)+dx(Vr))/2
    Sixx = dx(Ui)	
    Siyy = dy(Vi)	
    Sixy = (dy(Ui)+dx(Vi))/2	
  {real and imaginary parts of the stresses}
    Trxx= lambdaz*(Srxx+Sryy)+2*mu*Srxx-omega*beta*(lambdaz*(Sixx+Siyy)+2*mu*Sixx)
    Tryy= lambdaz*(Srxx+Sryy)+2*mu*Sryy-omega*beta*(lambdaz*(Sixx+Siyy)+2*mu*Siyy)
    Trxy=2*mu*(Srxy-omega*beta*Sixy)	
Tixx=lambdaz*(Sixx+Siyy)+2*mu*Sixx+ omega*beta*(lambdaz*(Srxx+Sryy)+2*mu*Srxx)
Tiyy=lambdaz*(Sixx+Siyy)+2*mu*Siyy+ omega*beta*(lambdaz*(Srxx+Sryy)+2*mu*Sryy)
    Tixy=2*mu*(Sixy+omega*beta*Srxy)	
  equations             
     Ur:  dx(Trxx) + dy(Trxy) + rho*omega^2*Ur - omega*alpha*rho*Ui = 0
     Ui:   dx(Tixx) + dy(Tixy) + rho*omega^2*Ui + omega*alpha*rho*Ur = 0
     Vr:   dx(Trxy) + dy(Tryy) + rho*omega^2*Vr - omega*alpha*rho*Vi = 0
     Vi:   dx(Tixy) + dy(Tiyy) + rho*omega^2*Vi + omega*alpha*rho*Vr = 0
boundaries
     Region 1        {upper region 1 from copper}
	start (0,H/2)
	natural(Ur)=0 natural(Vr)=0 natural(Ui)=0 natural(Vi)=0 {free boundary} line to (W,H/2) to (W,(H+FlangeT)/2) to (FlangeT,(H+FlangeT)/2)  
	line to (FlangeT,H-FlangeT) to (W,H-FlangeT) to (W,H)
    point load(Ur)=force  point load(Vr)=force
    line to (0,H) 
    point load(Ur)=-force  point load(Vr)=-force
    line to close
     Region 2         {lower region 2 from steel}
	{material properties for steel}
    nu = 0.29 E  = 2e11 rho = 7.86e3  
	start (0,H/2)
	natural(Ur)=0 natural(Vr)=0   natural(Ui)=0 natural(Vi)=0   {free boundary}
	line to (0,0) 
	value(Ur)=0  value(Vr)=0  value(Ui)=0  value(Vi)=0 {fixed displacements}
	line to (W,0)
	natural(Ur)=0 natural(Vr)=0   natural(Ui)=0 natural(Vi)=0   {free boundary}
	line to (W,FlangeT) to (FlangeT,FlangeT) to (FlangeT,(H-FlangeT)/2)
    line to (W,(H-FlangeT)/2) to (W,H/2) to close
  monitors
    elevation(Vr,Vi) from(0,H) to (W,H)
      report(omega)
  plots
    grid(x+Scal*Ur,y+Scal*Vr)   as "Real displacement"
      report(freq1)
    grid(x+Scal*Ui,y+Scal*Vi)   as "Imag displacement"
      report(freq1)
  end

Вещественная часть вектора перемещений

Мнимая часть вектора перемещений

	   FREQ               270 UY      
                      UY      
                       AMPLITUDE       PHASE   
    4.4000      0.896158E-004 -6.60115     
    4.6000      0.202794E-003 -17.2722     
    4.8000      0.322775E-003 -147.038     
    5.0000      0.890520E-004 -169.942     
    5.2000      0.474252E-004 -173.707     
                              ….
    15.400      0.106366E-003 -5.65904     
    15.600      0.194947E-003 -10.4661     
    15.800      0.850830E-003 -52.8855     
    16.000      0.265087E-003 -165.519     
    16.200      0.123463E-003 -173.265    
                              ….
    31.000      0.283779E-006 -49.3215     
    31.200      0.206347E-005 -20.9577     
    31.400      0.169227E-004 -70.9448     
    31.600      0.614362E-005 -169.960     
    31.800      0.379653E-005 -176.092 
                               ….
    40.400      0.655841E-005 -6.51132     
    40.600      0.124918E-004 -10.6972     
    40.800      0.493428E-004 -39.8008     
    41.000      0.240896E-004 -163.944     
    41.200      0.111282E-004 -173.430

Графике АЧХ вблизи второй резонансной частоты

График АЧХ вблизи третьей резонансной частоты

График АЧХ вблизи 1 резонансной частоты для нагрузки по оси X

График АЧХ вблизи 1 резонансной частоты для нагрузки по оси Y

	1 форма колебаний для нагрузки по OX
	1 форма колебаний для нагрузки по OY
	1 собственная форма колебаний

	[image: ]
	[image: ]
	[image: ]



ВЫВОД
Был проведен модальный и гармонический анализ для составного упругого профиля в форме буквы «Е» в условиях собственных колебаний и установившихся колебаний под воздействием точечной нагрузки. Были определены первые 4 собственные частоты и формы колебаний с помощью программ ANSYS и FlexPDE, а также построена амплитудно-частотная характеристика для установившихся колебаний с помощью программы ANSYS. Вблизи резонансных частот в условиях установившихся колебаний были определены формы колебаний с помощью программы FlexPDE.  Результаты моделирования в ANSYS и FlexPDE относительно собственных частот совпадают с отклонением 0,01%, формы колебаний совпадают с точностью до знака. Для установившихся колебаний видно, что деформированная форма для вещественной части вектора перемещений совпадает с формой колебаний, соответствующей второй собственной частоте, с точностью до знака.

