
РЕШЕНИЕ СТАЦИОНАРНОЙ ЗАДАЧИ ТЕПЛОПРОВОДНОСТИ
В ПЛОСКОЙ ОБЛАСТИ

	ЗАДАНИЕ
Требуется рассчитать поле температур, используя аналогичные физические входные данные, что и рассмотренном примере, но для области, соответствующей букве «У». Геометрические размеры областей надо придумать самостоятельно в диапазонах значений, аналогичных рассмотренному примеру. Геометрия области должна содержать хотя бы одну дугу окружности* или хотя бы одну дугу эллипса. Проведите расчеты в ANSYS и FlexPDE. На разных границах задайте граничные условия подачи температуры (снизу), теплообмена (сверху), остальные границы теплоизолированы. В Ansys проверьте сходимость результатов (температура и вектор потока тепла), проведя расчеты для различных размеров конечно-элементного разбиения, конечных элементов разной формы и порядка аппроксимации (треугольные PLANE35, четрырехугольные линейные PLANE55 и квадратичные элементы PLANE77). Сравните расчеты, полученные в ANSYS и FlexPDE.
РЕШЕНИЕ 
Решим задачу теплопроводности для области в форме буквы «У». Нагрев происходит по верхней правой (180) и левой (90) стенкам, на нижней левой грани буквы происходит конвективный теплообмен, остальные грани теплоизолированные. Температуру окружающей среды будем считать равной 0, коэффициент конвективного теплообмена = 60[], коэффициент теплопроводности = 46.7[]. Геометрические размеры указаны на рис. 1, где . Граничные условия можно увидеть на рис. 2.

	Рис. 1. Геометрические размеры области.
	Рис. 2. К-Э сетка и граничные условия.

	ТЕКСТ ПРОГРАММЫ ANSYS
	ТЕКСТ ПРОГРАММЫ FlexPDE

	/CLEAR
/TITLE, Heat Flow in 2D region
/PREP7

HL=5
WL=3
WWL=1
HAL=0.6

T_INP1=90   
T_INP2=180   
T_EXT=0	
H_F=60	

MP,KXX,1,46.7 

! Параметры для триангуляции
DMESH=WWL/5
DMESH1=DMESH/4

!ET,1,PLANE35
!ET,1,PLANE55
ET,1,PLANE77

PEL2=(HAL/2)/(WL-WWL)+1.2
LOCAL,12,1,0,HL/2,,,,,PEL2
CSYS,0

K,1,0,0
K,2,0,WWL
K,3,WWL,HL/2-WWL
K,4,0,HL
K,5,WWL,HL
K,6,WL/2,HL/2
K,7,WL-WWL,HL
K,8,WL,HL
K,9,WL-WWL,HL/2-WWL

L,1,2
L,3,4
L,4,5
L,5,6
L,6,7
L,7,8
L,8,9

CSYS,12
L,2,3
L,1,9

CSYS,0
AL,1,2,3,4,5,6,7,8,9

KESIZE,ALL,DMESH
KESIZE,1,DMESH1 $ KESIZE,2,DMESH1
KESIZE,3,DMESH1 $ KESIZE,6,DMESH1
AMESH,ALL 
FINISH

/SOLU
ANTYPE,STAT
OUTPR,ALL
OUTRES,ALL,ALL

NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0,WWL
SF,ALL,CONV,H_F,T_EXT 

NSEL,S,LOC,Y,HL	
NSEL,R,LOC,X,0,WWL
D,ALL,TEMP,T_INP1

NSEL,S,LOC,Y,HL	
NSEL,R,LOC,X,WL-WWL,WL
D,ALL,TEMP,T_INP2

NSEL,ALL
CSYS,0
SOLVE
SAVE,Heat_Letter_Y,db
FINISH

/POST1
SET,LAST

/SHOW,WIN32C
/TRIAD,OFF         
/PLOPTS,INFO,2     
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   
/PLOPTS,FRAME,OFF  
/PLOPTS,TITLE,OFF  
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF   

/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PBC,TEMP,,1	
/PSF,CONV,HCOEF,2 
PLNSOL,TEMP

PLVECT,TF,SUM
PLNSOL,TF,SUM
	TITLE "Heat Flow in 2D region - Letter E shape"

SELECT
    errlim = 1e-4
    ngrid =  24

VARIABLES
    T

DEFINITIONS
    HL = 5
    WL = 3
    WWL = 1
    HAL = 0.6 
    K = 46.7
    H_F = 60
    T_EXT = 0
    T_INP1 = 90
    T_INP2 = 180
    
    flux = -K*grad(T)
    
    PEL = (HAL/2)/(WL-WWL)+1.2

EQUATIONS
    div(flux) = 0


BOUNDARIES
  Region 1
    Start(0,0)
      Natural(T) = H_F * (T - T_EXT)
    Line to (0,WWL)
    
    	NATURAL(T) = 0
    ARC(CENTER=0, HL/2 ) TO (WWL, HL/2 -WWL)
    Line to (0,HL)
    
      Value(T) = T_INP1
    Line to (WWL,HL)
    
		Natural(T) = 0
    Line to (WL/2,HL/2)
    Line to (WL-WWL,HL)
    
      Value(T) = T_INP2
    Line to (WL,HL)
    
    	Natural(T) = 0
    Line to (WL-WWL,HL/2-WWL)
    ARC(CENTER=0, HL/2) TO (0, 0)

PLOTS
    grid(x,y) as "Finite element mesh"
    contour(T) painted as "Temperature"
    contour(magnitude(flux)) painted as "Heat flow vector magnitude"
    vector(flux) as "Heat Flow vector"

END

	Рис. 3. К-Э сетка из элементов PLANE35
	Рис. 4. К-Э сетка в программе FlexPDE

	Рис. 5. К-Э сетка из элементов PLANE55
	Рис. 6. К-Э сетка из элементов PLANE77

	Рис. 7. Распределение температуры ANSYS PLANE35
	Рис. 8. Распределение температуры FlexPDE

	Рис. 9. Распределение температуры ANSYS PLANE55
	Рис. 10. Распределение температуры ANSYS PLANE77

	Рис. 11. Распределение модуля вектора потока тепла ANSYS PLANE35
	Рис. 12. Распределение модуля вектора потока тепла ANSYS PLANE77

	Рис. 13. Распределение модуля вектора потока тепла ANSYS PLANE55
	Рис. 14. Распределение модуля вектора потока тепла FlexPDE

	Рис. 15. Распределение вектора потока тепла ANSYS PLANE35
	Рис. 16. Распределение вектора потока тепла ANSYS PLANE77

	Рис. 17. Распределение вектора потока тепла ANSYS PLANE55
	Рис. 18. Распределение вектора потока тепла FlexPDE



АНАЛИЗ СХОДИМОСТИ
	Сетка
	ANSYS PLANE35
	ANSYS PLANE55
	ANSYS PLANE77

	WWL/3
	9.662; 2686.31
	20.929; 2913.13
	23.027; 2804.0

	WWL/5
	5.941; 3251.45
	12.003; 2961.17
	12.088; 3010.4

	WWL/10
	2.088; 4225.39
	3.727; 3666.24
	3.784; 3629.63


Таб.1. Сходимость вектора потока (min; max).



	Сетка
	ANSYS PLANE35
	ANSYS PLANE55
	ANSYS PLANE77

	WWL/3
	20.401
	20.462
	20.434

	WWL/5
	20.305
	20.309
	20.309

	WWL/10
	20.305
	20.309
	20.309


Таб.2. Сходимость температуры (min).
ВЫВОД
Исходя из полученных результатов, можно сделать вывод, что полигоны типа Plane55 и Plane77 показывают схожие результаты. Значения типа Plane35 отличаются из-за другой формы элемента. Сходимость вектора потока сложно оценить из-за наличия сингулярности модуля вектора потока тепла в вершине острого угла выреза в верхней части пластины. При этом наблюдается сходимость по температуре и оптимальном разбиении сетки WWL/5. Результаты работы программ в ANSYS и FlexPDE дают примерно одинаковые значения. Максимальное совпадение с программой FlexPDE обеспечивает Plane35.

